F# - 模式匹配

---

---

模式匹配允許你“將資料與邏輯結構或結構進行比較，將資料分解成組成部分，或以各種方式從資料中提取資訊”。

換句話說，它提供了一種更靈活、更強大的方法來測試資料是否符合一系列條件，並根據滿足的條件執行一些計算。

從概念上講，它就像一系列 if… then 語句。

語法

從高階層面來看，F# 中的模式匹配遵循以下語法：

match expr with
| pat1 - result1
| pat2 -> result2
| pat3 when expr2 -> result3
| _ -> defaultResult

其中：

• 每個 | 符號定義一個條件。
• -> 符號表示“如果條件為真，則返回此值…”。
• _ 符號提供預設模式，這意味著它像萬用字元一樣匹配所有其他內容。

示例 1

以下示例使用模式匹配語法計算斐波那契數：

let rec fib n =
   match n with
   | 0 -> 0
   | 1 -> 1
   | _ -> fib (n - 1) + fib (n - 2)
for i = 1 to 10 do
   printfn "Fibonacci %d: %d" i (fib i)

編譯並執行程式後，將產生以下輸出：

Fibonacci 1: 1
Fibonacci 2: 1
Fibonacci 3: 2
Fibonacci 4: 3
Fibonacci 5: 5
Fibonacci 6: 8
Fibonacci 7: 13
Fibonacci 8: 21
Fibonacci 9: 34
Fibonacci 10: 55

你還可以將多個返回相同值的條件連結在一起。例如：

示例 2

let printSeason month =
   match month with
   | "December" | "January" | "February" -> printfn "Winter"
   | "March" | "April" -> printfn "Spring"
   | "May" | "June" -> printfn "Summer"
   | "July" | "August" -> printfn "Rainy"
   | "September" | "October" | "November" -> printfn "Autumn"
   | _ -> printfn "Season depends on month!"

printSeason "February"
printSeason "April"
printSeason "November"
printSeason "July"

編譯並執行程式後，將產生以下輸出：

Winter
Spring
Autumn
Rainy

模式匹配函式

F# 允許你使用 function 關鍵字編寫模式匹配函式：

let getRate = function
   | "potato" -> 10.00
   | "brinjal" -> 20.50
   | "cauliflower" -> 21.00
   | "cabbage" -> 8.75
   | "carrot" -> 15.00
   | _ -> nan (* nan is a special value meaning "not a number" *)

printfn "%g"(getRate "potato")
printfn "%g"(getRate "brinjal")
printfn "%g"(getRate "cauliflower")
printfn "%g"(getRate "cabbage")
printfn "%g"(getRate "carrot")

編譯並執行程式後，將產生以下輸出：

10
20.5
21
8.75
15

向模式新增過濾器或保護

你可以使用 when 關鍵字向模式新增過濾器或保護。

示例 1

let sign = function
   | 0 -> 0
   | x when x < 0 -> -1
   | x when x > 0 -> 1

printfn "%d" (sign -20)
printfn "%d" (sign 20)
printfn "%d" (sign 0)

編譯並執行程式後，將產生以下輸出：

-1
1
0

示例 2

let compareInt x =
   match x with
   | (var1, var2) when var1 > var2 -> printfn "%d is greater than %d" var1 var2
   | (var1, var2) when var1 < var2 -> printfn "%d is less than %d" var1 var2
   | (var1, var2) -> printfn "%d equals %d" var1 var2

compareInt (11,25)
compareInt (72, 10)
compareInt (0, 0)

編譯並執行程式後，將產生以下輸出：

11 is less than 25
72 is greater than 10
0 equals 0

使用元組進行模式匹配

以下示例演示了使用元組進行模式匹配：

let greeting (name, subject) =
   match (name, subject) with
   | ("Zara", _) -> "Hello, Zara"
   | (name, "English") -> "Hello, " + name + " from the department of English"
   | (name, _) when subject.StartsWith("Comp") -> "Hello, " + name + " from the department of Computer Sc."
   | (_, "Accounts and Finance") -> "Welcome to the department of Accounts and Finance!"
   | _ -> "You are not registered into the system"

printfn "%s" (greeting ("Zara", "English"))
printfn "%s" (greeting ("Raman", "Computer Science"))
printfn "%s" (greeting ("Ravi", "Mathematics"))

編譯並執行程式後，將產生以下輸出：

Hello, Zara
Hello, Raman from the department of Computer Sc.
You are not registered into the system

使用記錄進行模式匹配

以下示例演示了使用記錄進行模式匹配：

type Point = { x: float; y: float }
let evaluatePoint (point: Point) =
   match point with
   | { x = 0.0; y = 0.0 } -> printfn "Point is at the origin."
   | { x = xVal; y = 0.0 } -> printfn "Point is on the x-axis. Value is %f." xVal
   | { x = 0.0; y = yVal } -> printfn "Point is on the y-axis. Value is %f." yVal
   | { x = xVal; y = yVal } -> printfn "Point is at (%f, %f)." xVal yVal

evaluatePoint { x = 0.0; y = 0.0 }
evaluatePoint { x = 10.0; y = 0.0 }
evaluatePoint { x = 0.0; y = 10.0 }
evaluatePoint { x = 10.0; y = 10.0 }

編譯並執行程式後，將產生以下輸出：

Point is at the origin.
Point is on the x-axis. Value is 10.000000.
Point is on the y-axis. Value is 10.000000.
Point is at (10.000000, 10.000000).