PL/SQL - 變數

本章將討論 PL/SQL 中的變數。變數只不過是賦予程式可操作的儲存區域的名稱。PL/SQL 中的每個變數都有一個特定的資料型別，它決定了變數記憶體的大小和佈局；可以儲存在該記憶體中的值的範圍；以及可以應用於該變數的操作集。

PL/SQL 變數的名稱由一個字母組成，後面可以選擇跟上更多的字母、數字、美元符號、下劃線和井號，並且不應超過 30 個字元。預設情況下，變數名稱不區分大小寫。不能使用保留的 PL/SQL 關鍵字作為變數名。

PL/SQL 程式語言允許定義各種型別的變數，例如日期時間資料型別、記錄、集合等，我們將在後續章節中介紹。在本節中，讓我們只學習基本變數型別。

PL/SQL 中的變數宣告

PL/SQL 變數必須在宣告部分或包中作為全域性變數宣告。宣告變數時，PL/SQL 會為變數的值分配記憶體，並且儲存位置由變數名標識。

宣告變數的語法如下：

variable_name [CONSTANT] datatype [NOT NULL] [:= | DEFAULT initial_value]

其中，variable_name 是 PL/SQL 中的有效識別符號，datatype 必須是有效的 PL/SQL 資料型別或任何我們在上一章中已經討論過的使用者定義的資料型別。下面顯示了一些有效的變數宣告及其定義：

sales number(10, 2); 
pi CONSTANT double precision := 3.1415; 
name varchar2(25); 
address varchar2(100);

當您為資料型別提供大小、比例或精度限制時，這稱為約束宣告。約束宣告比非約束宣告需要更少的記憶體。例如：

sales number(10, 2); 
name varchar2(25); 
address varchar2(100);

PL/SQL 中的變數初始化

每當您宣告一個變數時，PL/SQL 都會為其分配 NULL 的預設值。如果您想使用非 NULL 值初始化變數，可以在宣告期間使用以下任一方法：

DEFAULT 關鍵字
賦值運算子

例如：

counter binary_integer := 0; 
greetings varchar2(20) DEFAULT 'Have a Good Day';

您還可以使用NOT NULL約束指定變數不應具有NULL值。如果您使用 NOT NULL 約束，則必須為該變數顯式分配初始值。

正確初始化變數是一個良好的程式設計習慣，否則，有時程式會產生意外的結果。嘗試以下示例，它使用了各種型別的變數：

DECLARE 
   a integer := 10; 
   b integer := 20; 
   c integer; 
   f real; 
BEGIN 
   c := a + b; 
   dbms_output.put_line('Value of c: ' || c); 
   f := 70.0/3.0; 
   dbms_output.put_line('Value of f: ' || f); 
END; 
/

執行上述程式碼時，會產生以下結果：

Value of c: 30 
Value of f: 23.333333333333333333  

PL/SQL procedure successfully completed.

PL/SQL 中的變數作用域

PL/SQL 允許巢狀塊，即每個程式塊可能包含另一個內部塊。如果變數在內部塊中宣告，則外部塊無法訪問它。但是，如果變數已宣告並可供外部塊訪問，則所有巢狀的內部塊也可以訪問它。變數作用域有兩種型別：

區域性變數 - 在內部塊中宣告的變數，外部塊無法訪問。
全域性變數 - 在最外層塊或包中宣告的變數。

以下示例以其簡單形式顯示了區域性和全域性變數的用法：

DECLARE 
   -- Global variables  
   num1 number := 95;  
   num2 number := 85;  
BEGIN  
   dbms_output.put_line('Outer Variable num1: ' || num1); 
   dbms_output.put_line('Outer Variable num2: ' || num2); 
   DECLARE  
      -- Local variables 
      num1 number := 195;  
      num2 number := 185;  
   BEGIN  
      dbms_output.put_line('Inner Variable num1: ' || num1); 
      dbms_output.put_line('Inner Variable num2: ' || num2); 
   END;  
END; 
/

執行上述程式碼時，會產生以下結果：

Outer Variable num1: 95 
Outer Variable num2: 85 
Inner Variable num1: 195 
Inner Variable num2: 185  

PL/SQL procedure successfully completed.

將 SQL 查詢結果賦給 PL/SQL 變數

您可以使用 SQL 的SELECT INTO語句將值賦給 PL/SQL 變數。對於SELECT 列表中的每個專案，都必須在INTO 列表中有一個相應的型別相容變數。以下示例說明了這個概念。讓我們建立一個名為 CUSTOMERS 的表：

(對於 SQL 語句，請參考 SQL 教程)

CREATE TABLE CUSTOMERS( 
   ID   INT NOT NULL, 
   NAME VARCHAR (20) NOT NULL, 
   AGE INT NOT NULL, 
   ADDRESS CHAR (25), 
   SALARY   DECIMAL (18, 2),        
   PRIMARY KEY (ID) 
);  

Table Created

現在讓我們在表中插入一些值：

INSERT INTO CUSTOMERS (ID,NAME,AGE,ADDRESS,SALARY) 
VALUES (1, 'Ramesh', 32, 'Ahmedabad', 2000.00 );  

INSERT INTO CUSTOMERS (ID,NAME,AGE,ADDRESS,SALARY) 
VALUES (2, 'Khilan', 25, 'Delhi', 1500.00 );  

INSERT INTO CUSTOMERS (ID,NAME,AGE,ADDRESS,SALARY) 
VALUES (3, 'kaushik', 23, 'Kota', 2000.00 );
  
INSERT INTO CUSTOMERS (ID,NAME,AGE,ADDRESS,SALARY) 
VALUES (4, 'Chaitali', 25, 'Mumbai', 6500.00 ); 
 
INSERT INTO CUSTOMERS (ID,NAME,AGE,ADDRESS,SALARY) 
VALUES (5, 'Hardik', 27, 'Bhopal', 8500.00 );  

INSERT INTO CUSTOMERS (ID,NAME,AGE,ADDRESS,SALARY) 
VALUES (6, 'Komal', 22, 'MP', 4500.00 );

以下程式使用 SQL 的SELECT INTO 子句將上述表中的值賦給 PL/SQL 變數：

DECLARE 
   c_id customers.id%type := 1; 
   c_name  customers.name%type; 
   c_addr customers.address%type; 
   c_sal  customers.salary%type; 
BEGIN 
   SELECT name, address, salary INTO c_name, c_addr, c_sal 
   FROM customers 
   WHERE id = c_id;  
   dbms_output.put_line 
   ('Customer ' ||c_name || ' from ' || c_addr || ' earns ' || c_sal); 
END; 
/

執行上述程式碼時，會產生以下結果：

Customer Ramesh from Ahmedabad earns 2000  

PL/SQL procedure completed successfully

列印頁面