如何檢查工作簿中每個工作表的尺寸？

眾所周知，當您右鍵單擊 Excel 檔案時，您可以檢視其屬性和大小。但是，當您想了解檔案內各個工作表的大小時該怎麼辦？

會計師和資料分析師維護包含多個工作表的大型 Excel 工作簿。瞭解檔案大小可以幫助確定分析它的最佳方法。有些人可能希望從較大的工作表開始，或者有些人可能希望從較小的工作表開始。通常，一張表佔據工作簿的大部分空間。

本教程說明如何在工作簿中識別每個工作表的大小。

用於確定 Excel 工作簿中工作表大小的 VBA 程式碼

您需要共享一個 Excel 檔案，但它太大而無法傳送。它包含 7 個工作表，您想知道哪個工作表可以縮減，以便可以有效地完成此任務。使用 Excel 中的 Visual Basic 應用程式 (VBA) 程式碼，您可以快速確定工作簿中所有工作表的大小，而不管工作簿中有多少個工作表，這些資訊都會顯示在一個獨立的工作表中。

步驟 1 - 開啟您要確定其中工作表大小的工作簿檔案。

步驟 2 - 轉到“開發工具”選項卡，然後單擊“Visual Basic”選項以開啟對話方塊。或者，您也可以透過按 Alt + F11 鍵開啟對話方塊。

步驟 3 - 對話框出現後，右鍵單擊“Microsoft Excel 物件”以獲取更多選項，然後選擇插入→模組。

步驟 4 - 將 VBA 程式碼鍵入或貼上到模組編輯器部分，該部分是螢幕右上側的白色框。

檢查工作簿中工作表大小的 Microsoft Excel VBA 程式碼 -

Sub WorksheetSizes()
   Dim wks As Worksheet
   Dim c As Range
   Dim sFullFile As String
   Dim sReport As String
   Dim sWBName As String
   sReport = "Size Report"
   sWBName = "Erase Me.xls"
   sFullFile = ThisWorkbook.Path & _
      Application.PathSeparator & sWBName
      ' Add new worksheet to record sizes
      On Error Resume Next
      Set wks = Worksheets(sReport)
      If wks Is Nothing Then
         With ThisWorkbook.Worksheets.Add(Before:=Worksheets(1))
            .Name = sReport
            .Range("A1").Value = "Worksheet Name"
            .Range("B1").Value = "Approximate Size"
         End With
      End If
      On Error GoTo 0
      With ThisWorkbook.Worksheets(sReport)
         .Select
         .Range("A1").CurrentRegion.Offset(1, 0).ClearContents
         Set c = .Range("A2")
      End With
      Application.ScreenUpdating = False
      ' Loop through worksheets
      For Each wks In ActiveWorkbook.Worksheets
         If wks.Name <> sReport Then
            wks.Copy
            Application.DisplayAlerts = False
            ActiveWorkbook.SaveAs sFullFile
            ActiveWorkbook.Close SaveChanges:=False
            Application.DisplayAlerts = True
            c.Offset(0, 0).Value = wks.Name
            c.Offset(0, 1).Value = FileLen(sFullFile)
            Set c = c.Offset(1, 0)
            Kill sFullFile
         End If
      Next wks
      Application.ScreenUpdating = True
End Sub