如何在 Excel 中加密/解密選定的單元格？

---

安全地處理敏感資料至關重要，Excel 具有內建工具，可讓您對電子表格中的單個單元格進行密碼保護。您可以透過加密和解密特定單元格來保護敏感資料免遭未經授權的訪問或意外更改。本文將逐步指導您完成加密和解密特定 Excel 單元格的過程。無論您需要保護銀行記錄、個人資料還是任何其他敏感資料，本手冊都將為您提供維護資訊安全的知識。

在開始之前，請確保您對 Microsoft Excel 的功能有基本的瞭解。如果您熟悉使用 Excel 介面以及處理單元格、行和列，將非常有幫助。請確保您的計算機上已安裝 Microsoft Excel，並且它支援加密功能。讓我們開始學習如何加密和解密特定的 Excel 單元格吧！

加密/解密選定的單元格

這裡我們將首先建立一個 VBA 模組，然後執行它來選擇單元格範圍、密碼，並加密或解密以完成任務。因此，讓我們看看一個簡單的過程，瞭解如何在 Excel 中加密或解密選定的單元格。

步驟 1

考慮一個 Excel 表格，其中包含專案列表。

首先，右鍵單擊工作表名稱，然後選擇“檢視程式碼”以開啟 VBA 應用程式。

右鍵單擊 > 檢視程式碼。

步驟 2

然後單擊“插入”，選擇“模組”，然後將以下程式碼複製到文字框中。

插入 > 模組 > 複製。

程式碼

Private Function StrToPsd(ByVal Txt As String) As Long
   Dim xVal As Long
   Dim xCh As Long
   Dim xSft1 As Long
   Dim xSft2 As Long
   Dim I As Integer
   Dim xLen As Integer
   xLen = Len(Txt)
   For I = 1 To xLen
      xCh = Asc(Mid$(Txt, I, 1))
      xVal = xVal Xor (xCh * 2 ^ xSft1)
      xVal = xVal Xor (xCh * 2 ^ xSft2)
      xSft1 = (xSft1 + 7) Mod 19
      xSft2 = (xSft2 + 13) Mod 23
   Next I
   StrToPsd = xVal
End Function
Private Function Encryption(ByVal Psd As String, ByVal InTxt As String, Optional ByVal Enc As Boolean = True) As String
   Dim xOffset As Long
   Dim xLen As Integer
   Dim I As Integer
   Dim xCh As Integer
   Dim xOutTxt As String
   xOffset = StrToPsd(Psd)
   Rnd -1
   Randomize xOffset
   xLen = Len(InTxt)
   For I = 1 To xLen
      xCh = Asc(Mid$(InTxt, I, 1))
      If xCh >= 32 And xCh <= 126 Then
         xCh = xCh - 32
         xOffset = Int((96) * Rnd)
         If Enc Then
            xCh = ((xCh + xOffset) Mod 95)
         Else
            xCh = ((xCh - xOffset) Mod 95)
            If xCh < 0 Then xCh = xCh + 95
         End If
         xCh = xCh + 32
         xOutTxt = xOutTxt & Chr$(xCh)
      End If
   Next I
   Encryption = xOutTxt
End Function
Sub EncryptionRange()
   Dim xRg As Range
   Dim xPsd As String
   Dim xTxt As String
   Dim xEnc As Boolean
   Dim xRet As Variant
   Dim xCell As Range
   On Error Resume Next
   xTxt = ActiveWindow.RangeSelection.Address
   Set xRg = Application.InputBox("Select a range:", "Encrypt Or Decrypt", xTxt, , , , , 8)
   Set xRg = Application.Intersect(xRg, xRg.Worksheet.UsedRange)
   If xRg Is Nothing Then Exit Sub
   xPsd = InputBox("Enter password:", " Encrypt Or Decrypt ")
   If xPsd = "" Then
      MsgBox "Password cannot be empty", , " Encrypt Or Decrypt "
      Exit Sub
   End If
   xRet = Application.InputBox("Type 1 to encrypt cell(s);Type 2 to decrypt cell(s)", " Encrypt Or Decrypt ", , , , , , 1)
   If TypeName(xRet) = "Boolean" Then Exit Sub
   If xRet > 0 Then
      xEnc = (xRet Mod 2 = 1)
      For Each xCell In xRg
         If xCell.Value <> "" Then
            xCell.Value = Encryption(xPsd, xCell.Value, xEnc)
         End If
      Next
   End If
End Sub

步驟 3

然後單擊 F5 執行模組。然後選擇要加密或解密的單元格範圍，然後單擊“確定”。

F5 > 選擇單元格 > 確定。

步驟 4

然後輸入密碼並單擊“確定”。

密碼 > 確定。

步驟 5

最後，選擇是加密還是解密，然後單擊“確定”。

選擇加密或解密 > 確定。

這就是如何在 Excel 中加密或解密選定單元格的方法。

結論

在本教程中，我們使用了一個簡單的示例來演示如何在 Excel 中加密或解密選定的單元格，以突出顯示特定資料集。